From e84db1121b206736eb2958322abd0830b068132d Mon Sep 17 00:00:00 2001
From: Piotr Jaroszyński
Date: Thu, 8 Apr 2010 01:25:38 +0200
Subject: [linux] Add linux platform skeleton

Add makefiles, ld scripts and default config for linux platform for
both i386 and x86_64.

Signed-off-by: Piotr Jaroszyński <p.jaroszynski@gmail.com>
Signed-off-by: Michael Brown <mcb30@ipxe.org>
---
 src/arch/x86_64/Makefile.linux    |   6 +++
 src/arch/x86_64/scripts/linux.lds | 101 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 107 insertions(+)
 create mode 100644 src/arch/x86_64/Makefile.linux
 create mode 100644 src/arch/x86_64/scripts/linux.lds

(limited to 'src/arch/x86_64')

diff --git a/src/arch/x86_64/Makefile.linux b/src/arch/x86_64/Makefile.linux
new file mode 100644
index 000000000..154f9d40d
--- /dev/null
+++ b/src/arch/x86_64/Makefile.linux
@@ -0,0 +1,6 @@
+LDSCRIPT = arch/x86_64/scripts/linux.lds
+
+SRCDIRS += arch/x86_64/core/linux
+
+MAKEDEPS += arch/x86/Makefile.linux
+include arch/x86/Makefile.linux
diff --git a/src/arch/x86_64/scripts/linux.lds b/src/arch/x86_64/scripts/linux.lds
new file mode 100644
index 000000000..34eb3561b
--- /dev/null
+++ b/src/arch/x86_64/scripts/linux.lds
@@ -0,0 +1,101 @@
+/* -*- sh -*- */
+
+/*
+ * Linker script for x86_64 Linux images
+ *
+ */
+
+OUTPUT_FORMAT ( "elf64-x86-64", "elf64-x86-64", "elf64-x86-64" )
+OUTPUT_ARCH ( i386:x86-64 )
+
+ENTRY ( _start )
+
+SECTIONS {
+	_max_align = 32;
+
+	. = 0x400000;
+
+	/*
+	 * The text section
+	 *
+	 */
+
+	. = ALIGN ( _max_align );
+	.text : {
+		_text = .;
+		*(.text)
+		*(.text.*)
+		_etext = .;
+	}
+
+	/*
+	 * The rodata section
+	 *
+	 */
+
+	. = ALIGN ( _max_align );
+	.rodata : {
+		_rodata = .;
+		*(.rodata)
+		*(.rodata.*)
+		_erodata = .;
+	}
+
+	/*
+	 * The data section
+	 *
+	 */
+
+	. = ALIGN ( _max_align );
+	.data : {
+		_data = .;
+		*(.data)
+		*(.data.*)
+		*(SORT(.tbl.*))		/* Various tables.  See include/tables.h */
+		_edata = .;
+	}
+
+	/*
+	 * The bss section
+	 *
+	 */
+
+	. = ALIGN ( _max_align );
+	.bss : {
+		_bss = .;
+		*(.bss)
+		*(.bss.*)
+		*(COMMON)
+		_ebss = .;
+	}
+
+	/*
+	 * Weak symbols that need zero values if not otherwise defined
+	 *
+	 */
+
+	.weak 0x0 : {
+		_weak = .;
+		*(.weak)
+		_eweak = .;
+	}
+	_assert = ASSERT ( ( _weak == _eweak ), ".weak is non-zero length" );
+
+	/*
+	 * Dispose of the comment and note sections to make the link map
+	 * easier to read
+	 *
+	 */
+
+	/DISCARD/ : {
+		*(.comment)
+		*(.comment.*)
+		*(.note)
+		*(.note.*)
+		*(.eh_frame)
+		*(.eh_frame.*)
+		*(.rel)
+		*(.rel.*)
+		*(.discard)
+	}
+}
-- 
cgit v1.2.3-55-g7522