1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
/*
* Copyright (C) 2008 Daniel Verkamp <daniel@drv.nu>.
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License as
* published by the Free Software Foundation; either version 2 of the
* License, or any later version.
*
* This program is distributed in the hope that it will be useful, but
* WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
* 02110-1301, USA.
*/
FILE_LICENCE ( GPL2_OR_LATER )
#include "librm.h"
.section ".note.GNU-stack", "", @progbits
.text
.code32
.globl com32_farcall_wrapper
com32_farcall_wrapper:
movl $VIRTUAL(com32_farcall), %eax
jmp com32_wrapper
.code32
.globl com32_cfarcall_wrapper
com32_cfarcall_wrapper:
movl $VIRTUAL(com32_cfarcall), %eax
jmp com32_wrapper
.code32
.globl com32_intcall_wrapper
com32_intcall_wrapper:
movl $VIRTUAL(com32_intcall), %eax
/* fall through */
.code32
com32_wrapper:
/* Disable interrupts */
cli
/* Switch to internal virtual address space */
call _phys_to_virt
#ifdef __x86_64__
.code64
/* Preserve registers which are callee-save for COM32 (i386 API) */
pushq %rdi
pushq %rsi
pushq %rbp
/* Extract parameters from stack */
movl 28(%rsp), %edi
movl 32(%rsp), %esi
movl 36(%rsp), %edx
/* Align stack pointer */
movq %rsp, %rbp
andq $~0x07, %rsp
/* Call helper function */
movslq %eax, %rax
call *%rax
/* Restore stack pointer */
movq %rbp, %rsp
/* Restore registers */
popq %rbp
popq %rsi
popq %rdi
#else /* _x86_64 */
/* Call helper function */
pushl 12(%esp)
pushl 12(%esp)
pushl 12(%esp)
call *%eax
addl $12, %esp
#endif /* _x86_64 */
/* Switch to external flat physical address space */
call _virt_to_phys
.code32
/* Reenable interrupts and return */
sti
ret
|
