summaryrefslogtreecommitdiffstats
path: root/src/installer/OpenSLX/OSExport/FileSystem/NFS.pm
blob: 96e40d240df884514ee22545a8c370556fba3ac9 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
# Copyright (c) 2006..2011 - OpenSLX GmbH
#
# This program is free software distributed under the GPL version 2.
# See http://openslx.org/COPYING
#
# If you have any feedback please consult http://openslx.org/feedback and
# send your suggestions, praise, or complaints to feedback@openslx.org
#
# General information about OpenSLX can be found at http://openslx.org/
# -----------------------------------------------------------------------------
# NFS.pm
#    - provides NFS-specific overrides of the OpenSLX::OSExport::FileSystem API.
# -----------------------------------------------------------------------------
package OpenSLX::OSExport::FileSystem::NFS;

use strict;
use warnings;

use base qw(OpenSLX::OSExport::FileSystem::Base);

use File::Basename;
use OpenSLX::Basics;
use OpenSLX::ConfigDB qw(:support);
use OpenSLX::Utils;

################################################################################
### interface methods
################################################################################
sub new
{
    my $class = shift;
    my $self = {
        'name' => 'nfs',
    };
    return bless $self, $class;
}

sub initialize
{
    my $self = shift;
    my $engine = shift;

    $self->SUPER::initialize($engine);
    
    my $exportBasePath = "$openslxConfig{'public-path'}/export";
    $self->{'export-path'} = "$exportBasePath/nfs/$engine->{'vendor-os-name'}";
    return;
}

sub exportVendorOS
{
    my $self = shift;
    my $source = shift;

    my $target = $self->{'export-path'};
    if ($self->_isTargetBindMounted($source, $target)) {
        warn _tr(
            "%s is a bind-mount to vendor-OS root - rsync step is skipped!",
            $target
        );
        return;
    }
    
    $self->_copyViaRsync($source, $target);

    return;
}

sub purgeExport
{
    my $self = shift;

    my $source = $self->{'engine'}->{'vendor-os-path'};
    my $target = $self->{'export-path'};
    if ($self->_isTargetBindMounted($source, $target)) {
        warn _tr(
            "%s is a bind-mount to vendor-OS root - removal step is skipped!",
            $target
        );
        return;
    }

    if (system("rm -r $target")) {
        vlog(0, _tr("unable to remove export '%s'!", $target));
        return 0;
    }
    return 1;
}

sub checkRequirements
{
    my $self         = shift;
    my $vendorOSPath = shift;

    # determine most appropriate kernel version ...
    my $kernelVer = $self->_pickKernelVersion($vendorOSPath);

    # ... and check if that kernel-version provides all the required modules
    my $nfsMod = $self->_locateKernelModule(
        $vendorOSPath,
        'nfs.ko',
        [
            "$vendorOSPath/lib/modules/$kernelVer/kernel/fs/nfs",
            "$vendorOSPath/lib/modules/$kernelVer/kernel/fs"
        ]
    );
    if (!defined $nfsMod) {
        warn _tr("unable to find nfs-module for kernel version '%s'.",
            $kernelVer);
        return;
    }
    return 1;
}

sub generateExportURI
{
    my $self = shift;
    my $export = shift;
    my $vendorOS = shift;

    my $serverIP = $export->{server_ip} || '';
    my $server 
        = length($serverIP) ? $serverIP : generatePlaceholderFor('serverip');
    my $port = $export->{port} || '';
    $server .= ":$port" if length($port);

    my $exportPath = "$openslxConfig{'public-path'}/export";
    return "nfs://$server$exportPath/nfs/$vendorOS->{name}";
}

sub requiredFSMods
{
    my $self = shift;

    return qw( nfs );
}

sub showExportConfigInfo
{
    my $self = shift;
    my $export = shift;

    print (('#' x 80)."\n");
    print _tr("Please make sure the following line is contained in /etc/exports\nin order to activate the NFS-export of this vendor-OS:\n\t%s\n",
              "$self->{'export-path'}\t*(ro,no_root_squash,async,no_subtree_check)");
    print (('#' x 80)."\n");

# TODO : add something a bit more clever here...
#    my $exports = slurpFile("/etc/exports");
    return;
}

################################################################################
### implementation methods
################################################################################
sub _copyViaRsync
{
    my $self = shift;
    my $source = shift;
    my $target = shift;

    if (system("mkdir -p $target")) {
        die _tr("unable to create directory '%s', giving up! (%s)\n",
                $target, $!);
    }
    my $includeExcludeList = $self->_determineIncludeExcludeList();
    vlog(1, _tr("using include-exclude-filter:\n%s\n", $includeExcludeList));
    my $rsyncFH;
    my $additionalRsyncOptions = $ENV{SLX_RSYNC_OPTIONS} || '';
    my $rsyncCmd
        = "rsync -av --numeric-ids --delete-excluded --exclude-from=- $additionalRsyncOptions"
            . " $source/ $target";
    vlog(2, "executing: $rsyncCmd\n");
    open($rsyncFH, '|-', $rsyncCmd)
        or die _tr("unable to start rsync for source '%s', giving up! (%s)",
                   $source, $!);
    print $rsyncFH $includeExcludeList;
    close($rsyncFH)
        or die _tr("unable to export to target '%s', giving up! (%s)",
                   $target, $!);
    return;
}

sub _determineIncludeExcludeList
{
    my $self = shift;

    # Rsync uses a first match strategy, so we mix the local specifications
    # in front of the filterset given by the package (as the local filters
    # should always overrule the vendor filters):
    my $distroName = $self->{engine}->{'distro-name'};
    my $localFilterFile 
        = "$openslxConfig{'config-path'}/distro-info/$distroName/export-filter";
    my $includeExcludeList 
        = slurpFile($localFilterFile, { failIfMissing => 0 });
    $includeExcludeList .= $self->{engine}->{distro}->{'export-filter'};
    $includeExcludeList =~ s[^\s+][]igms;
        # remove any leading whitespace, as rsync doesn't like it
    return $includeExcludeList;
}

sub _isTargetBindMounted
{
    my $self   = shift;
    my $source = shift;
    my $target = shift;

    # For development purposes, it is very desirable to be able to take a 
    # shortcut that avoids doing the actual copying of the folders (as that
    # takes a considerable amount of time).
    # In order to support this, we explicitly check if the OpenSLX NFS export
    # root folder (/srv/openslx/export/nfs) is a bind-mount of the OpenSLX 
    # stage1 folder (/var/opt/openslx/stage1).
    # If that is the case, we print a notice and skip the rsync step (which 
    # wouldn't work anyway, as source and target folder are the same).
    my $stage1Root = dirname($source);
    my $nfsRoot    = dirname($target);
    chomp(my $canonicalStage1Root = qx{readlink -f $stage1Root} || $stage1Root);
    chomp(my $canonicalNFSRoot    = qx{readlink -f $nfsRoot}    || $nfsRoot);
    my @mounts = slurpFile('/etc/mtab');
    for my $mount (@mounts) {
        if ($mount =~ m{
            ^
            $canonicalStage1Root    # mount source
            \s+
            $canonicalNFSRoot       # mount target
            \s+
            none                    # filesystem for bind mounts is 'none'
            \s+
            \S*\bbind\b\S*          # look for bind mounts only
        }gmsx) {
            return 1;
        }
    }
    return 0;
}

1;