blob: 04cabcf85ef983502622e4c0d46e2d43d9a02ef4 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
/*
* Linker script for RISC-V SBI images
*
*/
SECTIONS {
/* Weak symbols that need zero values if not otherwise defined */
saved_pos = .;
.weak 0x0 : {
_weak = .;
*(.weak)
*(.weak.*)
_eweak = .;
}
_assert = ASSERT ( ( _weak == _eweak ), ".weak is non-zero length" );
_assert = ASSERT ( ( . == saved_pos ), ".weak altered current position" );
/* Prefix code */
.prefix : {
_prefix = .;
*(.prefix)
*(.prefix.*)
_eprefix = .;
}
/* Program code */
.text : {
_text = .;
*(.text)
*(.text.*)
_etext = .;
}
/* Align to page size to allow linker to generate W^X segments */
. = ALIGN ( 4096 );
/* Read-only data */
.rodata : {
_rodata = .;
*(.srodata)
*(.srodata.*)
*(.rodata)
*(.rodata.*)
_erodata = .;
}
/* Writable data */
.data : {
_data = .;
*(.sdata)
*(.sdata.*)
*(.data)
*(.data.*)
KEEP(*(SORT(.tbl.*))) /* Various tables. See include/tables.h */
KEEP(*(.provided))
KEEP(*(.provided.*))
*(.got)
*(.got.plt)
/* Ensure compressed relocations end up aligned */
. = ALIGN ( 16 );
_edata = .;
}
/* Uninitialised and discardable data */
OVERLAY : {
/* Runtime relocations (discarded after use) */
.rela.dyn {
*(.rela)
*(.rela.dyn)
}
/* Compressor information block */
.zinfo {
_zinfo = .;
KEEP(*(.zinfo))
KEEP(*(.zinfo.*))
_ezinfo = .;
}
/* Uninitialised data */
.bss {
_bss = .;
*(.sbss)
*(.sbss.*)
*(.bss)
*(.bss.*)
*(COMMON)
*(.stack)
*(.stack.*)
/* Align to allow for easy zeroing by prefix code */
. = ALIGN ( 16 );
_ebss = .;
}
}
/* End virtual address */
_end = .;
/* Base virtual address */
_base = ABSOLUTE ( _prefix );
/* Relocations */
_reloc_offset = ( LOADADDR ( .rela.dyn ) - LOADADDR ( .prefix ) );
_reloc_filesz = SIZEOF ( .rela.dyn );
/* Length of initialised data */
_filesz = ( ABSOLUTE ( _edata ) - ABSOLUTE ( _prefix ) );
/* Length of in-memory image */
_memsz = ( ABSOLUTE ( _end ) - ABSOLUTE ( _prefix ) );
/* Unwanted sections */
/DISCARD/ : {
*(.comment)
*(.comment.*)
*(.note)
*(.note.*)
*(.eh_frame)
*(.eh_frame.*)
*(.dynamic)
*(.dynsym)
*(.dynstr)
*(.hash)
*(.gnu.hash)
*(.einfo)
*(.einfo.*)
*(.discard)
*(.discard.*)
*(.pci_devlist.*)
}
}
|
